This property replace the old fashion Actionscript 2 setRGB() method. Here’s the code for changing the color of a MovieClip in AS2:

var myColor:Color = new Color(myMovie);
     myColor.setRGB(0x4455ff);

where myMovie is an instance of a MovieClip.

For Actionscript 3 the code isn’t so complicated and here it is:

[/as3]
var newColor:ColorTransform = myMovie.transform.colorTransform;
     newColor.color = 0xFF5522;
     myMovie.transform.colorTransform = newColor;
[as3]

To see how the code works have a look at the example below:

The code for the example is here:

import flash.geom.ColorTransform;

square1.buttonMode = true;
square1.useHandCursor = true;
square1.mouseChildren = false;
square1.addEventListener("mouseOver", rollOverHandler);
square1.addEventListener("mouseOut", rollOutHandler);

square2.buttonMode = true;
square2.useHandCursor = true;
square2.mouseChildren = false;
square2.addEventListener("mouseOver", rollOverHandler);
square2.addEventListener("mouseOut", rollOutHandler);

function rollOverHandler(e:MouseEvent) {
	var newColor:ColorTransform = e.target.transform.colorTransform;
	if (e.target.name =="square1") {
		newColor.color = 0xFF5522;
	} else {
		newColor.color = 0x0066CC;
	}
	e.target.transform.colorTransform = newColor;

}

function rollOutHandler(e:MouseEvent) {
	var newColor:ColorTransform = e.target.transform.colorTransform;
	if (e.target.name =="square1") {
		newColor.color = 0x0066CC;
	} else {
		newColor.color = 0xFF5522;
	}
	e.target.transform.colorTransform = newColor;
}

Take a look at the example below for the final result.

1. For the first step I created the clock face. I drew 3 circles, and center align them. I used blue and grey colors with gradients for the background clock to look nice. I also made here the lines for the minutes and hours.

2. Create three new movie clips (Insert->New Symbol->Movie Clip) for seconds, minutes and hours clock hands. Inside each of them drew a coresponding shape. After that drag them on the Stage and center align to the clock. Give each Movie Clip an instance name (secondHand_, minuteHand_, hourHand_).

3. Final step paste this code in the Actions tab of the first frame. Once you’ve done that test the movie.

var timer:Timer = new Timer(1000);
timer.addEventListener(TimerEvent.TIMER, clockHandler);
timer.start();

function clockHandler(event:TimerEvent)
{

	    // set hour
		var time = new Date();
		var hourHand = time.getHours();
		var minuteHand = time.getMinutes();
		var secondHand = time.getSeconds();

		hourHand_.rotation = 30 * hourHand + minuteHand / 2;
		minuteHand_.rotation = 6 * minuteHand;
		secondHand_.rotation = 6 * secondHand;
}

Here is the final movie:

How is done:

1. Create the 3 small shapes and put them individually in a Movie Clip. Also give each of them an instance name (I call them item1, item2, item3).

2. Now for the large shape, create an empty Movie Clip (instance name bin1). Draw a circle without stroke and convert it to a Movie Clip. Give it an instance name of “shape” and place it at x=0 and y=0. Create a new layer and draw there a circle same width and height like the first one but without fill. Place it at the same coordinates.

3. For the triangle and rectangle follow the steps from point 2, except the empty Movie Clip instances.( rectangle - bin2 , triangle – bin3 )

4. Create two Dynamic TextFields (instance name itemName_txt and info_txt) and place them in a empty Movie Clip (instance name ilabel).

5. Final step copy the actionscript code bellow and paste it in the Actions tab.

item1.objName = "circle";
item1.initX = item1.x;
item1.initY = item1.y;
item1.val = 0;

item2.objName = "rectangle";
item2.initX = item2.x;
item2.initY = item2.y;
item2.val = 0;

item3.objName = "triangle";
item3.initX = item3.x;
item3.initY = item3.y;
item3.val = 0;

bin1.shape.alpha = 0;
bin2.shape.alpha = 0;
bin3.shape.alpha = 0;

item1.buttonMode = true;
item2.buttonMode = true;
item3.buttonMode = true;

item1.addEventListener(MouseEvent.MOUSE_DOWN, mousePress);
item1.addEventListener(MouseEvent.MOUSE_UP, mouseRelease);
item2.addEventListener(MouseEvent.MOUSE_DOWN, mousePress);
item2.addEventListener(MouseEvent.MOUSE_UP, mouseRelease);
item3.addEventListener(MouseEvent.MOUSE_DOWN, mousePress);
item3.addEventListener(MouseEvent.MOUSE_UP, mouseRelease);

//Mouse Events

function mousePress(event:MouseEvent):void {
	var item:MovieClip = MovieClip(event.target);
	item.startDrag();
	item.scaleX = item.scaleY = .95;
	var topPos:uint = this.numChildren - 1;
	this.setChildIndex(item, topPos);
	ilabel.itemName_txt.text = item.objName;
}

function mouseRelease(event:MouseEvent):void {
	var item:MovieClip = MovieClip(event.target);
	item.stopDrag();

	switch (item.objName) {
		case "circle" :
			if (bin1.hitTestObject(item)) {
				updateShape(item, bin1);

			} else {
				ilabel.info_txt.text ="WRONG!";
				item.scaleX = item.scaleY = 1;
			}
			break;
		case "rectangle" :
			if (bin2.hitTestObject(item)) {
				updateShape(item, bin2);

			} else {
				ilabel.info_txt.text ="WRONG!";
				item.scaleX = item.scaleY = 1;
			}
			break;
		case "triangle" :
			if (bin3.hitTestObject(item)) {
				updateShape(item, bin3);
			} else {
				ilabel.info_txt.text ="WRONG!";
				item.scaleX = item.scaleY = 1;
			}
			break;
		default :
			; ;
	}
}
function updateShape(item:MovieClip, bin:MovieClip):void {
	ilabel.itemName_txt.text = "";
	item.scaleX = item.scaleY = 1;
	item.visible = false;
	ilabel.info_txt.text ="CORRECT!";
	bin.shape.alpha = 1;
	item.val = 1;
	resetShapes();
}

function resetShapes() {
	if ((item1.val == 1)&& (item2.val == 1) && (item3.val == 1)) {

		item1.x = item1.initX;
		item1.y = item1.initY;
		item2.x = item2.initX;
		item2.y = item2.initY;
		item3.x = item3.initX;
		item3.y = item3.initY;

		bin1.shape.alpha = 0;
		bin2.shape.alpha = 0;
		bin3.shape.alpha = 0;

		item1.visible = true;
		item2.visible = true;
		item3.visible = true;

		item1.val = 0;
		item2.val = 0;
		item3.val = 0;

	}
}

So I came across this blog and found a useful tip for using the MouseWheel on Mac OS X, things being a little bit different here. This is done for ActionScript 3.0.

And since I was concerned myself on the matter I thought why not share it with you. It starts from SWFAddress add-on for deconcept’s SWFObject embedding system. We are going to add MouseWheel functionality to SWFObject.

In your main application class write the following code:

import com.pixelbreaker.ui.osx.MacMouseWheel;
MacMouseWheel.setup( stage );

After that you can add listeners to MovieClips, Sprites etc.

For downloading the source code take a visit to PixelBreaker. Also there is a JavaScript example to be used with dynamic embed method.

For those who want to know how you can use the MouseWheel for ActionScript 2.0 have a look at this post.

You may find some differences between browsers display of this MouseWheel effect on Mac but that’s because each browser has different fonts, size and display characteristics.

Browsers are the reason for this issue because they place embedded plug-in content, such as a Flash movie or Java applet, on the topmost layer. But newer browsers add the ability to use transparent backgrounds in the Flash content. Using the WMODE parameter we’ll be able to do layering of Flash content with DHTML layers. The WMODE parameter can be ‘window’ (default), ‘opaque’, or ‘transparent’.

So, for today’s tip we are going to learn how to make Flash movie with a transparent background.

It is important to know that the background of a Flash movie can be set to transparent which enables the background image or text to show through and allows the layering of Flash content with DHTML content.

Setting options to make the Flash movie transparent

We’re going to explain how it’s done in two ways.The first one in which we are going to use Flash for creating the HTML page and the movie. The second one contains HTML code that we can edit.

A. Using Flash

We’ll create the HTML for a Flash movie using the Publish Settings feature. This dialog box provides an option to affect the WMODE setting. The options selected will be added to the HTML source code automatically. Follow the steps and see for yourself the result.

1. Select the File menu -> Publish Settings

2. In the dialog box there is a Format tab: select the HTML (.html) option

3. Click the new HTML tab -> select the Window Mode menu

4. Select the Transparent Windowless option

5. Click Publish after finishing

That’s it. You can view the after effect.

B. Editing HTML manually

In order to edit an existing HTML file, we must add the WMODE parameters to the HTML code.

1. Add the following parameter to the OBJECT tag:

 <param name="wmode" value="transparent"> 

2. Add the following parameter to the EMBED tag:

 wmode="transparent" 

That pretty much covers the basic idea for setting the WMODE so that you can obtain a Flash movie with a transparent background.

1. Open Flash and create a new AS 3 file. (200×150)

2. Draw a rectangle(this will be our target object) and convert it to a movieclip. Give it an instance name of “mc”

3. Now we’ll create the tooltip movieclip. Draw a stroke and create a dynamic TextField. Name it “txt”. Select both and covert them to a movieclip “Tooltip”. For this one check the “Export for Actionscript” box. Delete the movieclip you just created from the stage because we’ll build an instance of it from Actionscript.

4. On the first frame of the stage, open up Actions tab and write this code:

import fl.transitions.easing.*;
import fl.transitions.*;

mc.addEventListener("mouseOver", mouseRollOver);
mc.addEventListener("mouseOut", mouseRollOut);
mc.addEventListener("mouseMove", mouseMove1);

var tooltip:Tooltip = new Tooltip();
tooltip.txt.text = "This is a tooltip";
tooltip.x = stage.mouseX;
tooltip.y = stage.mouseY - mc.height;

function mouseRollOver(e:MouseEvent):void {
	addChild(tooltip);
	var myTween:Tween = new Tween(tooltip, "alpha", Regular.easeIn, 0, 1, 0.5, true);

}

function mouseRollOut(e:MouseEvent):void {
	removeChild(tooltip);
}

function mouseMove1(e:MouseEvent):void {
	tooltip.x = stage.mouseX;
	tooltip.y = stage.mouseY - mc.height;
}

5. This is how your tooltip should look like, roll over the red rectangle to see the effect. Download the file

Here we go (this example is for Actionscript 3.0):

1. Create a MovieClip and give an instance name (e.g: myMovie)

2. Add an event listener to the movie you created:

myMovie.addEventListener("mouseDown",mousePress);

3. Create the mousePress function like so:

function mousePress(e:MouseEvent){

var url ="javascript:window.open('http://www.yoursite.com','title',
'width=800,height=600,toolbar=no,resizable=no,menubar=no,
status=no,scrollbars=no');void(0);";

var request1:URLRequest = new URLRequest(url);

	try {
  navigateToURL(request1);
         }
      catch (e:Error) {
  trace("Error occurred!");
}
}

4. Publish the movie and preview it in your browser.

1. Create a dynamic TextField and aligned to the right.

2. Give it an instance name, I call it countdown_txt.

3. In the first frame of the scene open the Actions tab and paste this code:

this.addEventListener("enterFrame",startMovie);

function startMovie(e:Event) {

	var today:Date = new Date();
	var curTime = today.getTime();

	var myRetirement:Date = new Date(2050, 7, 9);// 2050 August 9 -- months are from 0 to 11

	var myRetirementTime = myRetirement.getTime();// get the time in miliseconds of myRetirement
	var timeLeft = myRetirementTime-curTime;

	var seconds = Math.floor(timeLeft/1000);
	var minutes = Math.floor(seconds/60);
	var hours = Math.floor(minutes/60);
	var days = Math.floor(hours/24);
	var years = Math.floor(days/365);

	seconds = String(seconds%60);

	if (seconds.length<2) {
		seconds = "0"+seconds;
	}
	minutes = String(minutes%60);

	if (minutes.length<2) {
		minutes = "0"+minutes;
	}
	hours = String(hours%24);

	if (hours.length<2) {
		hours = "0"+hours;
	}
	days = String(days%365);

	if (days.length<2) {
		days = "0"+days;
	}
	years = String(years);

	var count:String = years+":"+days+":"+hours+":"+minutes+":"+seconds;
	countdown_txt.text = count;
}

Example:

1. Using the Text Tool(T) create 3 Textboxes(hours, minutes, seconds).

2. Give each one a name in the Var field of the Properties Panel.(for this example I use h – hours, m – minutes, s – seconds).

3. Write the following Actionscript code:

var dt
var timeint;

date = new Date();
h = date.getHours();
m = date.getMinutes();
s = date.getSeconds();
timeint = setInterval(displayZ, 1000);

function displayZ() {
   date = new Date();
   h = date.getHours();
   m = date.getMinutes();
   s = date.getSeconds();
   if (h<10) {
      h = "0"+h;
   }
   if (m<10) {
      m = "0"+m;
   }
   if (s<10) {
      s = "0"+s;
   }
}

4. If you want to display GMT Time(the example above uses Local Time) replace getHours() with getUTCHours, getMinutes() with getUTCMinutes() and getSeconds() with getUTCSeconds().

1. Prepare your xml file, here is the sample I will use:

<?xml version="1.0" encoding="utf-8" standalone="yes"?>
<images>

    <img image="photos/pic1.jpg" description="This is the first image" />

    <img image="photos/pic2.jpg" description="This is the second image" />

    <img image="photos/pic3.jpg"  description="This is the third image" />

</images>

2. The actionscript 3.0 code for extracting the xml file data:

var xmlData = "images.xml";//set xml data file

var xmlObj: XMLDocument;

init();//init call -> load config XML and create objects

function init() {
	xmlObj = new XMLDocument();
	xmlObj.ignoreWhite = true;

	var loader:URLLoader = new URLLoader();
	var request:URLRequest = new URLRequest(xmlData);
	loader.load(request);

	loader.addEventListener("complete", onComplete);
	loader.addEventListener("ioError", onIOError);
}

function onIOError(event:Event):void {
	trace("IOERROR (maybe XML file does not exit or have an incorrect name)");
}

function onComplete(event:Event):void {
	var loader:URLLoader = event.target as URLLoader;
	if (loader != null) {
		xmlObj.parseXML(loader.data);
		xmlHandler();
	} else {
		trace("Loader is not a URLLoader!");
	}
}

function xmlHandler() {
	addObjects();
}

var numItems;
var objects;

var image:Array = new Array();
var description:Array = new Array();

function addObjects() {//add objects in the scene

	objects = xmlObj.firstChild.childNodes;
	numItems = objects.length;

	for (var i=0; i<numItems; i++) {
		var attr = objects[i].attributes;
		//Set the images
		image[i] = attr.image;
		description[i] = attr.description;
		trace("Path image: "+image[i]+" ------description: "+description[i]);

	}
}

For any questions related to this method leave a comment and I will answer as soon as possible.

Here you can download the sample file.